使用 ZPL 存储格式，提高打印速度

本文介绍如何使用 ZPL 存储格式。

问题/疑问

使用 ZPL 存储格式。

适用于

ZPL 兼容打印机

议决/解答

Zebra打印机可以在其内存中存储模板并调用它以在相同布局上打印可变数据。建议使用 ZebraDesigner 版本 3 设计标签和“打印到文件”选项以获取 ZPL 代码进行修改。

可以使用以下 ZPL 命令执行此过程：

^DF

要将模板存储在打印机内存中：

^XF

要调用模板：

^FNx

填写变量字段。此命令后面必须跟一个标识变量字段本身的数字。
^DF和^XF命令后面必须跟内存字母和文件名，包括扩展名。

您可以使用的内存在此处列出：

R 为打印机 RAM。

E 为闪存。

如果您使用 R 内存，您将在重新启动打印机后丢失存储的模板。请记住，文件名不应超过 8 个字符（额外的字符将被截断）并且不能包含空格。

示例 1
此示例说明如何存储和调用没有可变字段的模板。

存储模板

^XA
^DFE:TEMPLATE.ZPL^FS
^FO50,50^A0,60,60^FDTest^FS
^XZ
^XA 是打开命令。
^DFE：TEMPLATE.ZPL是指示打印机存储文件而不是打印文件的命令。
^FO是字段来源； A是字体； FD 是数据字段。
^XZ是关闭命令。

调用模板^XA
^XFE:TEMPLATE.ZPL^FS
^PQ1
^XZ

^XF调用存储在内存 E 中的 TEMPLATE.ZPL 文件。
^PQ1 是打印数量。

示例 2
此示例说明如何使用^FN命令存储和调用具有可变字段的模板。

存储模板

^XA
^DFE:TEMPLATE.ZPL^FS
^FO25,25^A0N,50,50^FDName^FS
^FO25,75^A0N,50,50^FN1^FS
^FO25,125^A0N,50,50^FDSurname^FS
^FO25,175^A0N,50,50^FN2^FS
^XZ

第 3 行和第 5 行中的^FD字段是固定字段（姓名和姓氏）。
^FN1和^FN2是变量字段 1 和 2。

调用模板

^XA
^XFE:TEMPLATE.ZPL^FS
^FN1^FDJohn^FS
^FN2^FDDoe^FS
^PQ1
^XZ

^XF调用存储在内存 E 中的 TEMPLATE.ZPL 文件。
^FN1调用模板上的 ^FN1 字段并用“John”填充它。
^FN2调用模板上的 ^FN2 字段并用“Doe”填充它。

示例 3
如果您经常打印相同的标签，但其中一个字段是计数器，您可以使用 ^SN 命令调用包含计数器作为变量字段的保存格式。

存储模板

^XA
^DFE:TEMPLATE.ZPL^FS
^FO25,25^A0N,50,50^FDTest Model^FS
^FO25,125^A0N,50,50^FDSerial number^FS
^FO25,150^A0N,50,50^FN1^FS
^XZ

调用模板

^XA
^XFE:TEMPLATE.ZPL^FS
^FN1^SN123001,1^FS
^PQ100
^XZ

命令^SN将发送给打印机“123001”作为第一个标签的初始值，然后根据“1”，这是增量值。对于^PQ （打印数量）之后的值，它将打印 100 个标签，每个标签上的值递增 1（123001、123002...）。

如果您需要减小该值，则必须在数字前加上减号（EG，-1）。